1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
SUMMARY = "Toradex mainline Linux kernel"
SECTION = "kernel"
LICENSE = "GPL-2.0-only"
LIC_FILES_CHKSUM ?= "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
FILESEXTRAPATHS:prepend := "${THISDIR}/linux-toradex-mainline-git:"
DEPENDS += "coreutils-native"
# yaml and dtschema are required for 5.16+ device tree validation, libyaml is checked
# via pkgconfig, so must always be present, but we can wrap the others to make them
# conditional
DEPENDS += "libyaml-native"
PACKAGECONFIG ??= ""
PACKAGECONFIG[dt-validation] = ",,python3-dtschema-native"
# we need the wrappers if validation isn't in the packageconfig
DEPENDS += "${@bb.utils.contains('PACKAGECONFIG', 'dt-validation', '', 'python3-dtschema-wrapper-native', d)}"
PV = "${LINUX_VERSION}+git${SRCPV}"
LINUX_REPO = "git://git.kernel.org/pub/scm/linux/kernel/git/stable/linux.git"
SRC_URI = " \
${LINUX_REPO};protocol=https;branch=${KBRANCH};name=machine \
file://defconfig \
"
SRC_URI:append = " \
file://0001-thermal-imx-Update-critical-temp-threshold.patch \
file://0002-Revert-drm-panel-simple-drop-use-of-data-mapping-pro.patch \
file://0003-drivers-chipidea-disable-runtime-pm-for-imx6ul.patch \
file://0004-media-i2c-ov5640-Implement-get_mbus_config.patch \
"
LINUX_VERSION ?= "6.5-rc"
KBRANCH = "master"
KERNEL_VERSION_SANITY_SKIP = "1"
SRCREV_machine = "6aeadf7896bff4ca230702daba8788455e6b866e"
SRCREV_machine:use-head-next = "${AUTOREV}"
S = "${WORKDIR}/git"
KCONFIG_MODE="--alldefconfig"
# Load USB functions configurable through configfs (CONFIG_USB_CONFIGFS)
KERNEL_MODULE_AUTOLOAD += "${@bb.utils.contains('COMBINED_FEATURES', 'usbgadget', ' libcomposite', '',d)}"
inherit kernel-yocto kernel pkgconfig toradex-kernel-deploy-config toradex-kernel-localversion
# Additional file deployed by recent mainline kernels
FILES:${KERNEL_PACKAGE_NAME}-base += "${nonarch_base_libdir}/modules/${KERNEL_VERSION}/modules.builtin.modinfo"
export DTC_FLAGS = "-@"
# kconfiglib.KconfigError: init/Kconfig:70: error: couldn't parse 'default $(shell,$(srctree)/scripts/rust-version.sh $(RUSTC))': macro expanded to blank string
do_kernel_configcheck[noexec] = "1"
|
